Motivation: Warum Table Functions?

CDS Views reichen oft aus – aber manchmal braucht man mehr Features:

• Wenn komplexe Logik nötig ist
• Zugriff auf HANA-spezifische SQL-Funktionen oder SQLScript
• Dynamische Datenzugriffe
• Daten aus anderen DB-Schema

Dann kommen CDS Table Functions ins Spiel!

Was ist eine CDS Table Function?

• Kombination aus CDS-Definition & SQLScript-Logik
• Kein klassischer View – sondern:
  • CDS DDL-Quelltext
  • ABAP-Methode in einer AMDP-Klasse
• Rückgabe: Tabellarische Ergebnismenge wie bei CDS Views

Implementierung in AMDP

CLASS zcl_amdp_table_function DEFINITION
  PUBLIC FINAL
  CREATE PUBLIC.

  PUBLIC SECTION.
    INTERFACES if_amdp_marker_hdb.

    CLASS-METHODS CountryText FOR TABLE FUNCTION zi_table_function.

ENDCLASS.

CLASS zcl_amdp_table_function IMPLEMENTATION.
  METHOD countrytext BY DATABASE FUNCTION FOR HDB LANGUAGE SQLSCRIPT OPTIONS READ-ONLY
  USING t005t.

    TMP = select distinct mandt,
                          land1 as Country,
                          landx as CountryText
                   from t005t
                   where mandt = session_context( 'CLIENT' );

    return select mandt,
                  Country,
                  string_agg( CountryText, '/' ) as CountryText
                  from :TMP
                  group by Country, mandt;
  ENDMETHOD.
ENDCLASS.

Typische Use Cases

Komplexe Berechnungen
Viele aufeinander aufbauende Schritte
Verwendung von HANA-spezifischen Funktionen und Features, die im CDS nicht möglich sind. z.B. Window Functions
Zugriff auf andere Datenbankschema, z.B. _SYS_BIC

Demo - Table Function anlegen

define table function ZTF_TASKS_WITH_USER
  returns {
    task_key : abap.char(10);
    summary  : abap.char(80);
    user     : abap.char(40);
  }
implemented by method
  zcl_tasks_tf=>get_tasks.

AMDP-Klasse:

METHOD get_tasks BY DATABASE FUNCTION FOR HDB
LANGUAGE SQLSCRIPT OPTIONS READ-ONLY
USING zbc_tasks zbc_users.

RETURN
  SELECT t.task_key, t.summary, u.firstname || ' ' || u.lastname as user
    FROM zbc_tasks AS t
    JOIN zbc_users AS u ON t.assignee = u.user_id;