The Name of the CDS InfoProvider & Queries

Name of the Database View

To obtain the name of an InfoProvider or Query, we always need the name of the associated database view.

• DDIC-based CDS View: The annotation @AbapCatalog.sqlViewName
• CDS View Entities: The view name itself

Prefix 2C

To distinguish CDS-based InfoProviders and Queries from classic BW objects, SAP uses the prefix 2C.

The InfoProvider for the CDS View Entity ZI_DEMO_CUBE is called 2CZI_DEMO_CUBE.
The Query for the DDIC-based CDS View ZI_DEMO_QUERY is named after its SQL View ZVDEMOQUERY, resulting in 2CZVDEMOQUERY.

Use of the 2C Names

Relevant wherever an InfoProvider or Query name is required, including:

• Search in AFO (Analysis for Office)
• Ad-hoc queries in the Query Monitor (RSRT)

Ad-Hoc Queries on CDS InfoProviders

In Analysis for Office: If no query exists yet, search for the InfoProvider.

In the SAP Query Monitor (RSRT) you can query a CDS InfoProvider directly like any BW InfoProvider.
Enter in the Query field:
<InfoProvider>/!<InfoProvider>

Example: 2CZI_DEMO_CUBE/!2CZI_DEMO_CUBE

CDS Cube Views

• InfoProviders for measures – aggregation behavior matters for numeric values
• Dimensions are modeled as associations
• Used as sources for queries

Example I_SalesAnalyticsCube from the VDM

define view I_SalesAnalyticsCube
...
association [0..1] to   I_Customer  as _Customer  
        on  $projection.Customer = _Customer.Customer
...
{
//key
  key SalesDocument,
  key SalesDocumentItem, 

//Dimensions
  @ObjectModel.foreignKey.association: '_SoldToParty'
  SoldToParty,      

//Measures
  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  OpnSlsOrdsForOrdReltdInvcsQty,

CDS Dimension Views – Annotations

On View Level

@Analytics.dataCategory: #DIMENSION

Time Dependency

@Semantics.businessDate.from – Date-from field if time-dependent
@Semantics.businessDate.to – Date-to field

Texts for a Field

@ObjectModel.text.element: ['<text field>'] – On key field
@Semantics.text: true – On text field

Or via association:
@ObjectModel.text.association: '<AssociationName>'

CDS Dimension View – Example

@AbapCatalog.sqlViewName: 'SQL_VIEW_NAME'
@EndUserText.label: 'Material'

@Analytics.dataCategory: #DIMENSION
define view zjb_material_dim
  as select from /bi0/pmaterial as dim 

  association [0..*] to zjb_material_txt as _MaterialText
           on dim.material = _material_text.material
{
  @ObjectModel.text.association: '_MaterialText'
  key material,  
      changed,      
  @Semantics.systemDate.createdAt: true
      createdon,
      division,
      eanupc,
      ind_sector,
      matl_cat,
      matl_group,
      ...
}

CDS Text Views – Annotations

On View Level

@ObjectModel.dataCategory: #TEXT

On Field Level

@ObjectModel.text.element: [ 'Text' ]
@Semantics.text: true – Text field
@Semantics.language: true – Language field (optional)
@Semantics.businessDate.from – Date-from field
@Semantics.businessDate.to – Date-to field

CDS Queries

• A CDS Query inherits semantic properties from its InfoProvider
• It defines the layout and initial drilldown of the data

define transient view entity <query name> provider contract analytical_query as projection on <cube name>

CDS Queries – Filter Parameter Annotations

Alternative to input parameters.

  @EndUserText.label: 'Product'
  @Consumption.filter:{ selectionType:      #RANGE,       // #INTERVAL, #SINGLE, #HIERARCHY_NODE
                        multipleSelections: false,
                        mandatory:          true,
                        hidden:             false,
                        defaultValue:       '0000000000011675'  }

  @AnalyticsDetails.query:{ hidden: false,                           
                            display: #KEY_TEXT }  
  Product

CDS Queries – Annotations for Key Figures

@AnalyticsDetails.query:{ axis:     #COLUMNS,
                          decimals: 2,
                          scaling:  0,
                          hidden:   false
}
 quant_b,

  @EndUserText.label: 'Profit'
  @AnalyticsDetails.query:{ formula: '(price_vk - price_vek) * nodim(quant_b)' }
  1 as profit, 

  @EndUserText.label: 'Different Materials'
  @AnalyticsDetails.exceptionAggregationSteps:
              [{ exceptionAggregationBehavior: #COUNT,
                 exceptionAggregationElements: ['material'] }]
  1 as materialCount