Code Under Test (CUT)

Mit dem Kürzel CUT bezeichnet man das zu testenden Objekt. Diese Abkürzung heißt, je nach Kontext entweder Code under Test oder Class under Test oder sogar CDS under Test.

Diese Abkürzung wird auch häufig in Testklassen verwendet.

Laufzeit und Risikostufe - Empfehlungen

Laufzeit

Wir legen nach Möglichkeit schnelle Tests an, d.h. solche die deutlich weniger als eine Sekunde dauern. Damit ist die Durchführung jederzeit ohne Warten möglich.

Risikostufe

Unsere Tests verändern Persistente Daten nicht. Wenn wir Logik gegen Datenbankzustände testen wollen, verwenden wir das Test Double Framework.

Falls wir von den obigen beiden Punkten abweichen, brauchen wir einen sehr guten Grund.

Setup - Fixture

Das zu testende Objekt (CUT) wird vor dem Test erzeugt und mit einem fest definierten Zustand (aka. Fixture) gebracht.

Falls dieser Schritt nicht trivial ist, wird dazu die Methode SETUP() definiert. Diese wird vor der Ausführung jeder Testmethode vom UnitTest Framework aufgerufen.

Analog dazu wird, falls vorhanden, am Ende die TEARDOWN() Methode aufgerufen. Hier können Dinge nach dem Test aufgeräumt werden.

Zeitlicher Ablauf bei Unit Tests

• Schleife über alle Testklassen einer Klasse
  • Aufruf der statischen Methode CLASS_SETUP()
  • Schleife über alle Testmethoden
    • Erzeugung einer Instanz der Testklasse
    • Aufruf der Instanzmethode SETUP()
    • Aufruf der Testmethode
    • Aufruf der Instanzmethode TEARDOWN()
  • Aufruf der statischen Methode CLASS_TEARDOWN()
  • Ausführen von ROLLBACK WORK

Methoden der Klasse CL_ABAP_UNIT_ASSERT

Die meisten Methoden der Klasse haben den gleichen Parameter:

    METHODS  assert_Equals
        importing   value(act)              type any
                    value(exp)              type any
                    ignore_Hash_Sequence    type abap_Bool default abap_False
                    tol                     type f optional
                    msg                     type csequence optional
                    level                   type int1 default if_Abap_Unit_Constant=>severity-medium
                    quit                    type int1 default if_Abap_Unit_Constant=>quit-test
        returning   value(assertion_Failed) type abap_Bool,

Was macht gute Tests aus

• Die Durchführung ist schnell
• Es werden alle Aspekte abgefragt:
  • Happy Path: Die gewünschte Funktion
  • Fehlersituationen testen: Leere Parameter, negative Eingaben, etc.
• Alle Zweige innerhalb des CUT sollen getestet worden sein

Zugriff von Testklassen auf Private Daten

CLASS ltc_board DEFINITION DEFERRED  .

CLASS zbc_board DEFINITION LOCAL FRIENDS ltc_board.

CLASS ltc_board DEFINITION FINAL FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.

Unterschiedliche Test-Doubles

Es gibt unterschiedliche Arten von Test-Doubles:

• Dummy - Ein leeres Objekt, das keine Funktion hat. Außer das es die notwendigen Schnittstellen hat.
• Stub - Ein Objekt das vorgegebene Daten zurückgibt
• Mock-Objekt - Ein Objekt das komplexere Logik implementiert

Test Doubles können manuell erzeugt werden. Das ist aber aufwändig. Alternativ gibt es mehrere Mocking-Frameworks:

• SAP MockA von Uwe Kunath
• SAP Test Double Framework
• SAP ABAP SQL Test Double Framework (auch als Downport von 7.51 auf 7.02 )
• SAP ABAP CDS Test Double Framework - mit Assistent zur Erzeugung der Test Doubles

Vom Dummy zum Stub

Wenn das Double Objekt Daten zurückgeben soll, dann müssen die ganz konkreten Methodenaufrufe zuvor konfiguriert werden:

1. Zunächst wird der Rückgabewert definiert
2. Danach wird dann in einem Aufruf des Dummy Objektes mit den entsprechenden Parameterwerten festgelegt, wann die zuvor definierten Rückgabewerte zurückgegeben werden solle.

    "Definiere Rückgabewert....
    cl_abap_testdouble=>configure_call( lo_sorter_double )->returning( 
                         VALUE zif_sort=>tt_sort(  ( `Ali` )
                                                   ( `Jörg` )
                                                  ( `Manfred` ) ) ).
    "... für diesen Methodenaufruf:
    lo_sorter_double->sort( VALUE #( ( `Jörg` )
                                     ( `Ali` )
                                     ( `Manfred` ) ) ).

Für alle anderen Werte werden initiale Daten zurückgegeben.

ABAP SQL Test Double Framework

    methods select_data 
       importing iv_project type zbc_project_key
       RETURNING VALUE(result) type tt_tasks.
...
  METHOD SELECT_DATA.

    select *
      from zbc_tasks
      where project = @iv_project
      into table @result .


  ENDMETHOD.

  method t_select.

    data(environment) = cl_osql_test_environment=>create( 
      i_dependency_list = value #( (  'ZBC_TASKS' ) ) ).
    data(mock_data)   = 
    value zbc_ut_demo=>tt_tasks( client = sy-mandt 
     ( project = 'A' task_key = 'A-1' )
                            ( project = 'B' task_key = 'B-1' )
                            ( project = 'A' task_key = 'A-2' ) )  .
    environment->insert_test_data( i_data = mock_data ).
    data(result) = new zbc_ut_demo( )->select_data( 'A' ).

    cl_abap_unit_assert=>assert_equals( exp = value zbc_ut_demo=>tt_tasks(
       client = sy-mandt ( project = 'A' task_key = 'A-1' )
       ( project = 'A' task_key = 'A-2' ) )
                                        act = result ).

  endmethod.

Testbarer Code

Viele Clean Code Prinzipien erleichtern die Erstellung von testbarem Code. Beispiele:

• Kleine Methoden mit genau einer Aufgabe - Klare Testfälle
• Wenige Parameter - Wenige Tests pro Methode notwendig, weil es nur wenige Kombinationen gibt
• Trennung durch Interfaces - Das Test Double Framework kann eingesetzt werden
• Klassen mit nur einer Verantwortlichkeit - Eine Trennung eines betriebswirtschaftlichen Objektes (z.B. Benutzer) in mehrere Klassen mit technischen Verantwortlichkeiten kann hilfreich sein, weil beispielsweise die Klasse für den Datenbankzugriff durch ein Test Double ersetzt werden kann

Grundsätzlich bauen wir keine "Abzweigungen" in den Code ein, damit die Tests leichter fallen:

IF p_is_test.
  SELECT * 
    FROM <Tabelle>
    INTO TABLE @lt_table.
ELSE. 
  lt_table = VALUE #( ( salesorderdocument = '10000' 
                        AMOUNT = '123,56'
                        ... ))
ENDIF.