Tabellenausdrücke

Tabellenausdrücke sollen den lesende und schreibende Zugriff auf einzelne Zeilen und deren Felder vereinfachen. Sie ersetzen somit READ ... INTO und READ ... ASSIGNING Anweisungen und teilweise auch LOOP-Schleifen.

Tabellenausdrücke liefern eine Tabellenzeile*

*In SQL würde man sie deshalb Zeilenausdrücke nennen

Beispiele für Tabellenausdrücke

    SELECT *
      FROM zbc_users
      INTO TABLE @DATA(lt_user).

    DATA(ls_first_row) = lt_user[ 1 ].

    DATA(lv_firstname) = lt_user[ 1 ]-firstname.

    DATA(lv_lastname_of_Binky) = lt_user[ firstname = 'Binky' ]-lastname.

    out->write( lv_lastname_of_binky ).

An den Beispielen sieht man schön: Es ist auch möglich auf Komponenten der Struktur zuzugreifen. Und wenn diese Komponenten wieder eine Tabelle sind, dann könnte man auch dort wieder einen Pfadausdruck platzieren...

Alternatve zur Exception - Verwendung im VALUE Konstruktorausdruck

Falls kein Datensatz durchdie Zeilenspezialisierung gefunden wird, kann man statt einer Exception auch einen leere Zeile erhalten. Oder eine Alternative Zeile. Dazu wird der Tabellenausdruck in einen VALUE Konstruktorausdruck gepackt:

...VALUE #( <Tabelle>[<Zeilenspezifikation>] 
             DEFAULT <Alternativer Tabellenausdruck> | OPTIONAL )

Alternative mit DEFAULT

Falls der ursprüngliche Tabellenausdruck scheitert, dann wird der Wert des alternativen Tabellenausdrucks verwendet. Dieser kann natürlich auch wieder in einem VALUE Operator stecken...

Initiale Zeile mit OPTIONAL

Wenn hinter dem Tabellenausdruck im VALUE das Schlüsselwort OPTIONAL steht, dann wird bei gescheitertem Zeilenzugriff eine initiale Zeile zurückgegeben.

Schreibposition von Tabellenausdrücken

Ein Tabellenausdruck ist zunächst ein Pointer auf die mit der Zeilenspezifikation angegebene Zeile. Das bedeutet, dass diese auch geändert werden kann.

Welche Zeilen werde hier wirklich geändert?

    DATA(lt_data) = get_user_table( ).

    lt_data[ user_id = 1 ]-firstname = 'Olaf'.

    DATA(ls_data) = lt_data[ 2 ].
    ls_data-firstname = 'Teddy'.

    ASSIGN lt_data[ 3 ] TO FIELD-SYMBOL(<ls_data>).
    <ls_data>-firstname = 'Anke'.

    out->write( lt_data ).

Tabellenfunktionen

LINES( <Tabelle> ) liefert die Anzahl der Datensätze in der Tabelle als Ausdruck. D.h. es kann direkt als Operator für alles mögliche verwendet werden.

LINE_INDEX( <Tabellenausdruck> ) liefert die Zeilennummer der durch den Tabellenausdruck festgelegten Zeile.

        SELECT *
      FROM zbc_users
      INTO TABLE @DATA(lt_user).

      out->write( |Binky steht in Zeile { line_index( lt_user[ firstname = 'Binky' ]  ) }| ).
  

Beispiel für Sekundärindex

Für alle Aufgaben: Gibt es eine Aufgabe mit der gleichen Summary, und wenn ja, wie viele?

    TYPES: BEGIN OF ts_tasks,
             task_key TYPE zbc_tasks-task_key,
             cnt      TYPE int4,
             summary  TYPE zbc_tasks-summary,
           END OF ts_tasks.
    DATA: lt_standard TYPE STANDARD TABLE OF ts_tasks DEFAULT KEY
                         WITH NON-UNIQUE SORTED KEY sumKey COMPONENTS summary.
  ...
    LOOP AT lt_standard ASSIGNING FIELD-SYMBOL(<ls_standard>).
      CLEAR cnt.
      LOOP AT lt_standard TRANSPORTING NO FIELDS 
                          USING KEY sumKey 
                          WHERE summary = <ls_standard>-summary.
        cnt += 1.
      ENDLOOP.
      <ls_standard>-cnt = cnt.
    ENDLOOP.

ITAB - LOOP AT ... GROUP BY - Syntax

LOOP AT <Table>
        <Line> 
        [<Condition>]
        GROUP BY <GroupingKey>
        [<Sorting>]
        [WITHOUT MEMBERS]
        [<GroupingResult>]
   ...
   LOOP AT GROUP <GroupingResult> 
        <Result>
        [WHERE <LogExpr>]
        [GROUP BY ... ] 

    ENDLOOP     
   ...
ENDLOOP.      

Beispiel nur Gruppierung

Im einfachsten Falle wird nur gruppiert, ohne dann über die Gruppe zu Loopen. Daran sieht man den Charakter des äußeren Loops

    loop at lt_user into data(ls_user) 
                    group by ls_user-gender.
        out->write( ls_user ).
    endloop.

Ergebnis:

Structure
CLIENT  USER_ID     FIRSTNAME  LASTNAME  EMAIL               GENDER  DATE_OF_BIRTH  
100     0000000001  Emmye      Alywen    ealywen0@alexa.com  F       1976-05-16     
Structure  
CLIENT  USER_ID     FIRSTNAME  LASTNAME      EMAIL                       GENDER  DATE_OF_BIRTH  
100     0000000003  Stavro     Antonopoulos  santonopoulos2@histats.com  M       2000-09-16     

In LS_USER steht immer eine ganze Zeile der Tabelle. Da es in den Daten genau zwei Ausprägungen des Feldes GENDER gibt, wurden hier 2 Gruppen gebildet und wir sehen jeweils eine Zeile davon in der Ausgabe.

LOOP über die Gruppenstruktur

Im LOOP über die Daten der Gruppe repräsentiert die Gruppenstruktur die entsprechende Tabelle.

    LOOP AT lt_user INTO DATA(ls_user)
                    GROUP BY ls_user-gender
                    INTO DATA(ls_grouping).

      out->write( |At begin of gender { ls_grouping } | ).

      LOOP AT GROUP ls_grouping INTO DATA(ls_group).
        out->write( ls_group-firstname ).
      ENDLOOP.

      out->write( |At end of gender { ls_grouping } | ).
    ENDLOOP.

At begin of gender F 
   Emmye
   Yolande
   Heidi
   Constantina
   Martica
At end of gender F 
At begin of gender M 
   Stavro
   Peyter
   Gonzalo
   Thibaut
At end of gender M